📚 The CoCalc Library - books, templates and other resources

cocalc-examples / cocalc-example-files / sage / SageManifolds / SM_de_Sitter.sagews

¹³³⁹⁵⁷ views
License: OTHER

%auto
typeset_mode(True, display=False)

de Sitter spacetime

This worksheet demonstrates a few capabilities of SageManifolds (version 0.8) in computations regarding de Sitter spacetime.

It is released under the GNU General Public License version 3.

The corresponding worksheet file can be downloaded from here

Spacetime manifold

We declare the de Sitter spacetime as a 4-dimensional differentiable manifold:

M = Manifold(4, 'M', r'\mathcal{M}')
print M ; M

4-dimensional manifold 'M'

$\mathcal{M}$

We consider hyperspherical coordinates $(\tau,\chi,\theta,\phi)$ on $\mathcal{M}$. Allowing for the standard coordinate singularities at $\chi=0$, $\chi=\pi$, $\theta=0$ or $\theta=\pi$, these coordinates cover the entire spacetime manifold (which is topologically $\mathbb{R}\times\mathbb{S}^3$). If we restrict ourselves to regular coordinates (i.e. to consider only mathematically well defined charts), the hyperspherical coordinates cover only an open part of $\mathcal{M}$, which we call $\mathcal{M}_0$, on which $\chi$ spans the open interval $(0,\pi)$, $\theta$ the open interval $(0,\pi)$ and $\phi$ the open interval $(0,2\pi)$. Therefore, we declare:

M0 = M.open_subset('M_0', r'\mathcal{M}_0')
X_hyp.<ta,ch,th,ph> = M0.chart(r'ta:\tau ch:(0,pi):\chi th:(0,pi):\theta ph:(0,2*pi):\phi')
print X_hyp ; X_hyp

chart (M_0, (ta, ch, th, ph))

$\left(\mathcal{M}_0,({\tau}, {\chi}, {\theta}, {\phi})\right)$

$\mathbb{R}^5$ as an ambient space

The de Sitter metric can be defined as that induced by the embedding of $\mathcal{M}$ into a 5-dimensional Minkowski space, i.e. $\mathbb{R}^5$ equipped with a flat Lorentzian metric. We therefore introduce $\mathbb{R}^5$ as a 5-dimensional manifold covered by canonical coordinates:

R5 = Manifold(5, 'R5', r'\mathbb{R}^5')
X5.<T,W,X,Y,Z> = R5.chart()
print X5 ; X5

chart (R5, (T, W, X, Y, Z))

$\left(\mathbb{R}^5,(T, W, X, Y, Z)\right)$

The embedding of $\mathcal{M}$ into $\mathbb{R}^5$ is defined as a differential mapping $\Phi$ from $\mathcal{M}$ to $\mathbb{R}^5$, by providing its expression in terms of $\mathcal{M}$'s default chart (which is X_hyp = $(\mathcal{M}_0,(\tau,\chi,\theta,\phi))$ ) and $\mathbb{R}^5$'s default chart (which is X5 = $(\mathbb{R}^5,(T,W,X,Y,Z))$ ):

var('b')
Phi = M.diff_mapping(R5, [sinh(b*ta)/b,
                          cosh(b*ta)/b * cos(ch),
                          cosh(b*ta)/b * sin(ch)*sin(th)*cos(ph),
                          cosh(b*ta)/b * sin(ch)*sin(th)*sin(ph),
                          cosh(b*ta)/b * sin(ch)*cos(th)],
                  name='Phi', latex_name=r'\Phi')
print Phi ; Phi.display()

$b$

differentiable mapping 'Phi' from the 4-dimensional manifold 'M' to the 5-dimensional manifold 'R5'

$\begin{array}{llcl} \Phi:& \mathcal{M} & \longrightarrow & \mathbb{R}^5 \\ \mbox{on}\ \mathcal{M}_0 : & \left({\tau}, {\chi}, {\theta}, {\phi}\right) & \longmapsto & \left(T, W, X, Y, Z\right) = \left(\frac{\sinh\left(b {\tau}\right)}{b}, \frac{\cos\left({\chi}\right) \cosh\left(b {\tau}\right)}{b}, \frac{\cos\left({\phi}\right) \cosh\left(b {\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right)}{b}, \frac{\cosh\left(b {\tau}\right) \sin\left({\chi}\right) \sin\left({\phi}\right) \sin\left({\theta}\right)}{b}, \frac{\cos\left({\theta}\right) \cosh\left(b {\tau}\right) \sin\left({\chi}\right)}{b}\right) \end{array}$

The constant $b$ is a scale parameter. Considering de Sitter metric as a solution of vacuum Einstein equation with positive cosmological constant $\Lambda$, one has $b = \sqrt{\Lambda/3}$.

Let us evaluate the image of a point via the mapping $\Phi$:

p = M.point((ta, ch, th, ph), name='p') ; print p

point 'p' on 4-dimensional manifold 'M'

p.coord()

(${\tau}$, ${\chi}$, ${\theta}$, ${\phi}$)

q = Phi(p) ; print q

point 'Phi(p)' on 5-dimensional manifold 'R5'

q.coord()

($\frac{\sinh\left(b {\tau}\right)}{b}$, $\frac{\cos\left({\chi}\right) \cosh\left(b {\tau}\right)}{b}$, $\frac{\cos\left({\phi}\right) \cosh\left(b {\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right)}{b}$, $\frac{\cosh\left(b {\tau}\right) \sin\left({\chi}\right) \sin\left({\phi}\right) \sin\left({\theta}\right)}{b}$, $\frac{\cos\left({\theta}\right) \cosh\left(b {\tau}\right) \sin\left({\chi}\right)}{b}$)

The image of $\mathcal{M}$ by $\Phi$ is a hyperboloid of one sheet, of equation $-T^2+W^2+X^2+Y^2+Z^2=b^{-2}$. Indeed:

(Tq,Wq,Xq,Yq,Zq) = q.coord()
s = -Tq^2 + Wq^2 + Xq^2 + Yq^2 + Zq^2
s.simplify_full()

$\frac{1}{b^{2}}$

We may use the embedding $\Phi$ to draw the coordinate grid $(\tau,\chi)$ in terms of the coordinates $(W,X,T)$ for $\theta=\pi/2$ and $\phi=0$ (red) and $\theta=\pi/2$ and $\phi=\pi$ (green) (the brown lines are the lines $\tau={\rm const}$):

graph1 = X_hyp.plot(X5, mapping=Phi, ambient_coords=(W,X,T), fixed_coords={th:pi/2, ph:0}, nb_values=9, color={ta:'red', ch:'brown'}, thickness=2, max_value=2, parameters={b:1}, label_axes=False)
graph2 = X_hyp.plot(X5, mapping=Phi, ambient_coords=(W,X,T), fixed_coords={th:pi/2, ph:pi}, nb_values=9, color={ta:'green', ch:'brown'}, thickness=2, max_value=2, parameters={b:1}, label_axes=False)
show(set_axes_labels(graph1+graph2,'W','X','T'), aspect_ratio=1)

3D rendering not yet implemented

Spacetime metric

First, we introduce on $\mathbb{R}^5$ the Minkowski metric $h$:

h = R5.lorentz_metric('h')
h[0,0], h[1,1], h[2,2], h[3,3], h[4,4] = -1, 1, 1, 1, 1
h.display()

$h = -\mathrm{d} T\otimes \mathrm{d} T+\mathrm{d} W\otimes \mathrm{d} W+\mathrm{d} X\otimes \mathrm{d} X+\mathrm{d} Y\otimes \mathrm{d} Y+\mathrm{d} Z\otimes \mathrm{d} Z$

As mentioned above, the de Sitter metric $g$ on $\mathcal{M}$ is that induced by $h$, i.e.$g$ is the pullback of $h$ by the mapping $\Phi$:

g = M.metric('g')
g.set( Phi.pullback(h) )

The expression of $g$ in terms of $\mathcal{M}$'s default frame is found to be

g.display()

$g = -\mathrm{d} {\tau}\otimes \mathrm{d} {\tau} + \frac{\cosh\left(b {\tau}\right)^{2}}{b^{2}} \mathrm{d} {\chi}\otimes \mathrm{d} {\chi} + \frac{\cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2}}{b^{2}} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \frac{\cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2}}{b^{2}} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

g[:]

$\left(\begin{array}{rrrr} -1 & 0 & 0 & 0 \\ 0 & \frac{\cosh\left(b {\tau}\right)^{2}}{b^{2}} & 0 & 0 \\ 0 & 0 & \frac{\cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2}}{b^{2}} & 0 \\ 0 & 0 & 0 & \frac{\cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2}}{b^{2}} \end{array}\right)$

Curvature

The Riemann tensor of $g$ is

Riem = g.riemann()
print Riem
Riem.display()

tensor field 'Riem(g)' of type (1,3) on the 4-dimensional manifold 'M'

$\mathrm{Riem}\left(g\right) = \cosh\left(b {\tau}\right)^{2} \frac{\partial}{\partial {\tau} }\otimes \mathrm{d} {\chi}\otimes \mathrm{d} {\tau}\otimes \mathrm{d} {\chi} -\cosh\left(b {\tau}\right)^{2} \frac{\partial}{\partial {\tau} }\otimes \mathrm{d} {\chi}\otimes \mathrm{d} {\chi}\otimes \mathrm{d} {\tau} + \cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \frac{\partial}{\partial {\tau} }\otimes \mathrm{d} {\theta}\otimes \mathrm{d} {\tau}\otimes \mathrm{d} {\theta} -\cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \frac{\partial}{\partial {\tau} }\otimes \mathrm{d} {\theta}\otimes \mathrm{d} {\theta}\otimes \mathrm{d} {\tau} + \cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \frac{\partial}{\partial {\tau} }\otimes \mathrm{d} {\phi}\otimes \mathrm{d} {\tau}\otimes \mathrm{d} {\phi} -\cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \frac{\partial}{\partial {\tau} }\otimes \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}\otimes \mathrm{d} {\tau} + b^{2} \frac{\partial}{\partial {\chi} }\otimes \mathrm{d} {\tau}\otimes \mathrm{d} {\tau}\otimes \mathrm{d} {\chi} -b^{2} \frac{\partial}{\partial {\chi} }\otimes \mathrm{d} {\tau}\otimes \mathrm{d} {\chi}\otimes \mathrm{d} {\tau} + \cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \frac{\partial}{\partial {\chi} }\otimes \mathrm{d} {\theta}\otimes \mathrm{d} {\chi}\otimes \mathrm{d} {\theta} -\cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \frac{\partial}{\partial {\chi} }\otimes \mathrm{d} {\theta}\otimes \mathrm{d} {\theta}\otimes \mathrm{d} {\chi} + \cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \frac{\partial}{\partial {\chi} }\otimes \mathrm{d} {\phi}\otimes \mathrm{d} {\chi}\otimes \mathrm{d} {\phi} -\cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \frac{\partial}{\partial {\chi} }\otimes \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}\otimes \mathrm{d} {\chi} + b^{2} \frac{\partial}{\partial {\theta} }\otimes \mathrm{d} {\tau}\otimes \mathrm{d} {\tau}\otimes \mathrm{d} {\theta} -b^{2} \frac{\partial}{\partial {\theta} }\otimes \mathrm{d} {\tau}\otimes \mathrm{d} {\theta}\otimes \mathrm{d} {\tau} + \left( -\frac{\sin\left({\chi}\right)^{2} \sinh\left(b {\tau}\right)^{2} - \cos\left({\chi}\right)^{2} + 1}{\sin\left({\chi}\right)^{2}} \right) \frac{\partial}{\partial {\theta} }\otimes \mathrm{d} {\chi}\otimes \mathrm{d} {\chi}\otimes \mathrm{d} {\theta} + \cosh\left(b {\tau}\right)^{2} \frac{\partial}{\partial {\theta} }\otimes \mathrm{d} {\chi}\otimes \mathrm{d} {\theta}\otimes \mathrm{d} {\chi} + \cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \frac{\partial}{\partial {\theta} }\otimes \mathrm{d} {\phi}\otimes \mathrm{d} {\theta}\otimes \mathrm{d} {\phi} -\cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \frac{\partial}{\partial {\theta} }\otimes \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}\otimes \mathrm{d} {\theta} + b^{2} \frac{\partial}{\partial {\phi} }\otimes \mathrm{d} {\tau}\otimes \mathrm{d} {\tau}\otimes \mathrm{d} {\phi} -b^{2} \frac{\partial}{\partial {\phi} }\otimes \mathrm{d} {\tau}\otimes \mathrm{d} {\phi}\otimes \mathrm{d} {\tau} + \left( -\frac{\sin\left({\chi}\right)^{2} \sinh\left(b {\tau}\right)^{2} - \cos\left({\chi}\right)^{2} + 1}{\sin\left({\chi}\right)^{2}} \right) \frac{\partial}{\partial {\phi} }\otimes \mathrm{d} {\chi}\otimes \mathrm{d} {\chi}\otimes \mathrm{d} {\phi} + \cosh\left(b {\tau}\right)^{2} \frac{\partial}{\partial {\phi} }\otimes \mathrm{d} {\chi}\otimes \mathrm{d} {\phi}\otimes \mathrm{d} {\chi} -\cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \frac{\partial}{\partial {\phi} }\otimes \mathrm{d} {\theta}\otimes \mathrm{d} {\theta}\otimes \mathrm{d} {\phi} + \cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \frac{\partial}{\partial {\phi} }\otimes \mathrm{d} {\theta}\otimes \mathrm{d} {\phi}\otimes \mathrm{d} {\theta}$

Riem.display_comp(only_nonredundant=True)

$\begin{array}{lcl} \mathrm{Riem}\left(g\right)_{ \phantom{\, {\tau} } \, {\chi} \, {\tau} \, {\chi} }^{ \, {\tau} \phantom{\, {\chi} } \phantom{\, {\tau} } \phantom{\, {\chi} } } & = & \cosh\left(b {\tau}\right)^{2} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {\tau} } \, {\theta} \, {\tau} \, {\theta} }^{ \, {\tau} \phantom{\, {\theta} } \phantom{\, {\tau} } \phantom{\, {\theta} } } & = & \cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {\tau} } \, {\phi} \, {\tau} \, {\phi} }^{ \, {\tau} \phantom{\, {\phi} } \phantom{\, {\tau} } \phantom{\, {\phi} } } & = & \cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {\chi} } \, {\tau} \, {\tau} \, {\chi} }^{ \, {\chi} \phantom{\, {\tau} } \phantom{\, {\tau} } \phantom{\, {\chi} } } & = & b^{2} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {\chi} } \, {\theta} \, {\chi} \, {\theta} }^{ \, {\chi} \phantom{\, {\theta} } \phantom{\, {\chi} } \phantom{\, {\theta} } } & = & \cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {\chi} } \, {\phi} \, {\chi} \, {\phi} }^{ \, {\chi} \phantom{\, {\phi} } \phantom{\, {\chi} } \phantom{\, {\phi} } } & = & \cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {\theta} } \, {\tau} \, {\tau} \, {\theta} }^{ \, {\theta} \phantom{\, {\tau} } \phantom{\, {\tau} } \phantom{\, {\theta} } } & = & b^{2} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {\theta} } \, {\chi} \, {\chi} \, {\theta} }^{ \, {\theta} \phantom{\, {\chi} } \phantom{\, {\chi} } \phantom{\, {\theta} } } & = & -\frac{\sin\left({\chi}\right)^{2} \sinh\left(b {\tau}\right)^{2} - \cos\left({\chi}\right)^{2} + 1}{\sin\left({\chi}\right)^{2}} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {\theta} } \, {\phi} \, {\theta} \, {\phi} }^{ \, {\theta} \phantom{\, {\phi} } \phantom{\, {\theta} } \phantom{\, {\phi} } } & = & \cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {\phi} } \, {\tau} \, {\tau} \, {\phi} }^{ \, {\phi} \phantom{\, {\tau} } \phantom{\, {\tau} } \phantom{\, {\phi} } } & = & b^{2} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {\phi} } \, {\chi} \, {\chi} \, {\phi} }^{ \, {\phi} \phantom{\, {\chi} } \phantom{\, {\chi} } \phantom{\, {\phi} } } & = & -\frac{\sin\left({\chi}\right)^{2} \sinh\left(b {\tau}\right)^{2} - \cos\left({\chi}\right)^{2} + 1}{\sin\left({\chi}\right)^{2}} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {\phi} } \, {\theta} \, {\theta} \, {\phi} }^{ \, {\phi} \phantom{\, {\theta} } \phantom{\, {\theta} } \phantom{\, {\phi} } } & = & -\cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \end{array}$

The Ricci tensor:

Ric = g.ricci()
print Ric
Ric.display()

field of symmetric bilinear forms 'Ric(g)' on the 4-dimensional manifold 'M'

$\mathrm{Ric}\left(g\right) = -3 \, b^{2} \mathrm{d} {\tau}\otimes \mathrm{d} {\tau} + 3 \, \cosh\left(b {\tau}\right)^{2} \mathrm{d} {\chi}\otimes \mathrm{d} {\chi} + 3 \, \cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + 3 \, \cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

Ric[:]

$\left(\begin{array}{rrrr} -3 \, b^{2} & 0 & 0 & 0 \\ 0 & 3 \, \cosh\left(b {\tau}\right)^{2} & 0 & 0 \\ 0 & 0 & 3 \, \cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} & 0 \\ 0 & 0 & 0 & 3 \, \cosh\left(b {\tau}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \end{array}\right)$

The Ricci scalar:

R = g.ricci_scalar()
print R
R.display()

scalar field 'r(g)' on the 4-dimensional manifold 'M'

$\begin{array}{llcl} \mathrm{r}\left(g\right):& \mathcal{M} & \longrightarrow & \mathbb{R} \\ \mbox{on}\ \mathcal{M}_0 : & \left({\tau}, {\chi}, {\theta}, {\phi}\right) & \longmapsto & 12 \, b^{2} \end{array}$

We recover the fact that de Sitter spacetime has a constant curvature. It is indeed a maximally symmetric space. In particular, the Riemann tensor is expressible as

\[ R^i_{\ \, jlk} = \frac{R}{n(n-1)} \left( \delta^i_{\ \, k} g_{jl} - \delta^i_{\ \, l} g_{jk} \right) \]

where $n$ is the dimension of $\mathcal{M}$: $n=4$ in the present case. Let us check this formula here, under the form $R^i_{\ \, jlk} = -\frac{R}{6} g_{j[k} \delta^i_{\ \, l]}$:

delta = M.tangent_identity_field() 
Riem == - (R/6)*(g*delta).antisymmetrize(2,3)  # 2,3 = last positions of the type-(1,3) tensor g*delta

$\mathrm{True}$

We may also check that de Sitter metric is a solution of the vacuum Einstein equation with (positive) cosmological constant:

Lambda = 3*b^2
Ric - 1/2*R*g + Lambda*g == 0

$\mathrm{True}$

de Sitter spacetime

Spacetime manifold

$\mathbb{R}^5$ as an ambient space

Spacetime metric

Curvature

Product

Resources

Company